Pushables: A DIY Approach for Fabricating Customizable And Self-Contained Tactile Membrane Dome Switches

/* Pushables: A DIY Approach for Fabricating Customizable
 * and Self-Contained Tactile Membrane Dome Switches
 * - Konstantin Klamka & Raimund Dachselt -
 * 
 * Sketch for a simple semi-automatic embossing machine.
 * 
 * This sketch controls a stepper motor. By triggering a 
 * push-button the motor moves a linear actuator 534 steps 
 * down (see EMBOSSING_DISTANCE), waits four secounds (see 
 * EMBOSSING_TIME) and moves a the linear actuator back in 
 * its position. The temperature-controlled solder iron 
 * with the attached upholstery nail is not part of the 
 * arduino sketch since we use a commercial solder iron 
 * station.
 *  
 * created 2018 by 
 * Konstantin Klamka
 * Interactive Media Lab Dresden, Germany
 * 
 * This example code is in the public domain.
 * 
 * Project website:
 * http://www.imld.de/pushables/
 * 
 * ----------------------------------------
 * 
 * The hardware: 
 * Arduino Mega 2560 Rev3, Easy Driver Stepper Motor Driver, 
 * stepper motor from an old printer, laboratory power supply
 * temperature-controlled solder iron with an attached upholstery
 * nail, linear actuator (we used 3D-printed parts that are 
 * available on our project website).
 *  
 * The circuit:
 * 
 * push-button 
 * pin 53 and ground
 * 
 * Easy Driver Stepper Motor Driver: 
 * DIR  : pin 12
 * STEP : pin 13
 * GND  : ground
 * PWR IN: external laboratory power supply (12V, 1A)
 * 
 * ----------------------------------------
  */
 
// ---- Pins ------
#define DIR_PIN 12
#define STEP_PIN 13
#define BUTTON_PIN 53

// ---- Embossing Parameters ------
#define EMBOSSING_DISTANCE  534  // steps
#define EMBOSSING_TIME      4000 // milliseconds

// ---- Setup ------
void setup() {                
  
  // Set Pin Modes
  pinMode(DIR_PIN, OUTPUT);     
  pinMode(STEP_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);

  digitalWrite(DIR_PIN, HIGH);
  digitalWrite(STEP_PIN, LOW);
}

// ---- loop ------
void loop() {

  // Read the push-button value into a variable
  int button_state = digitalRead(BUTTON_PIN);

  // Keep in mind the pull-up means the pushbutton's 
  // logic is inverted. It goes HIGH when it's open, 
  // and LOW when it's pressed.
  if (button_state == LOW){

    digitalWrite(DIR_PIN, HIGH);

    // move temperature-controlled solder iron 
    // with the attached upholstery nail down
    for(int i = 0; i<EMBOSSING_DISTANCE;i++){
      digitalWrite(STEP_PIN, LOW); 
      delay(1);
      digitalWrite(STEP_PIN, HIGH);
      delay(1);      
    }

    // wait while the heated upholstery nail 
    // embosses the PVC foil...
    delay(EMBOSSING_TIME);

    // move temperature-controlled solder iron 
    // with the attached upholstery nail up...
    digitalWrite(DIR_PIN, LOW);
    for(int i = 0; i<EMBOSSING_DISTANCE;i++){
      digitalWrite(STEP_PIN, LOW); 
      delay(1);
      digitalWrite(STEP_PIN, HIGH);
      delay(1);      
    }
    
    digitalWrite(DIR_PIN, HIGH);
    } 
}

G28
G1 Z20 F1200
M104 S100 T0
M109 S100 T0
G1 X50 Y50 F2400
G1 Z1 F1200
G4 P4000
G1 Z20 F1200
M104 S0 T0
G1 X0 Y0 F2400 ;